wmpasman Git

66 lines (55 with data), 1.8 kB

# Process this file with autoconf to produce a configure script.
AC_INIT([wmpasman], [2.2])
AM_CONFIG_HEADER(config.h)
AM_INIT_AUTOMAKE()
AM_SILENT_RULES([yes])

DATE=`date '+%B %e, %Y'`
AC_SUBST(DATE)
AC_SUBST(VERSION)

# Checks for programs.
AC_PROG_AWK
AC_PROG_CC
AC_PROG_CC_STDC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_RANLIB

AX_CHECK_LINKER_FLAGS([-Wl,--as-needed],
 [LDFLAGS="$LDFLAGS -Wl,--as-needed"],
 [:]
)

# Checks for libraries.
AC_CHECK_LIB(m, round)
PKG_CHECK_MODULES(libsecret,libsecret-1)

# For SecretValue
PKG_CHECK_MODULES(libsecret_unstable,libsecret-unstable)

# Checks for header files.
AC_PATH_XTRA
AM_PATH_GTK_3_0(3.8.0,,[AC_MSG_ERROR(cannot find libgtk3)])
PKG_CHECK_MODULES(gdk_pixbuf,gdk-pixbuf-2.0)
AC_HEADER_STDC
if test "$ac_cv_header_stdc" != "yes"; then AC_MSG_WARN(standard C headers not found); fi
AC_CHECK_HEADERS([string.h sys/statvfs.h],, AC_MSG_WARN($ac_header not found))
AC_HEADER_TIME

# Checks for typedefs, structures, and compiler characteristics.
AC_C_CONST
AC_C_INLINE
AC_TYPE_SIZE_T

# Checks for library functions.
AC_REPLACE_FUNCS([pipe2])
AC_MSG_CHECKING([for prctl and PR_SET_DUMPABLE])
AC_COMPILE_IFELSE([AC_LANG_SOURCE([
#include <sys/prctl.h>
int main(void){
    prctl(PR_SET_DUMPABLE, 0);
    return 0;
}
])],[
   AC_DEFINE(HAVE_PRCTL,1,[Define if the Linux prctl is available and PR_SET_DUMPABLE is defined])
   AC_MSG_RESULT([yes])
],[AC_MSG_RESULT([no])])

X_CFLAGS="$X_CFLAGS \$(GTK_CFLAGS) \$(gdk_pixbuf_CFLAGS) \$(libsecret_CFLAGS) \$(libsecret_unstable_CFLAGS)"
X_LIBS="\$(X_PRE_LIBS) $X_LIBS -lX11 \$(gdk_pixbuf_LIBS) \$(X_EXTRA_LIBS) \$(GTK_LIBS) \$(libsecret_LIBS) \$(libsecret_unstable_LIBS)"

AC_CONFIG_FILES([Makefile])
AC_CONFIG_FILES([m4/Makefile])
AC_CONFIG_FILES([b0rken/Makefile])
AC_OUTPUT